1、思路

  • 借用十进制除法竖式计算的思路，作十六进制的除法竖式计算。
    将除数3字节与被除数高3字节对齐，除完后保存当前字节的商和余数，将被除数往低顺延一个字节，再执行新一轮的除法。被除数有6字节，除数有3字节，故除法需执行4轮。这是最外层的循环。
  • 每一轮的除法可转换为多次减法，需要注意的是，对被除数来说减法需要一直执行到最高字节，以保证借位执行无误。这是中间层的循环。
  • 每一轮的减法由单个字节的减法循环组成，减的过程中考虑借位。由于除数只有3个字节，执行完此3次减法后，除数再往上的字节内容为00H，减法就变成了XXH-CY-00H，即纯粹的借位。
  • 为了判断中间层循环什么时候结束，需要额外写一个子程序来比较减数与被减数的大小，这个子程序只做比较，不改变存储内容，返回后能还原寄存器的值。

2、流程图

根据上述思路绘制的流程图如下：

FlowChart

顺便一提，这里的流程图是使用SmartDraw官网在线编辑器绘制的，有一说一，还挺好用的，安利一下QwQ

这里是后期的Kuuhaku，想说一下，markdown是支持代码绘制流程图更加方便，如果不执着于可视化操作的话可以上手试试

3、源代码

这里分享一下本项目的源代码

首先需要声明的是，在本代码中被除数从高到低依次存于25H ~ 20H六个字节，除数由高到低依次存于32H ~ 30H三个字节

主程序如下：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
		MOV R0,#23H		;首轮除法的被除数起始字节，也是余数的存储字节
		MOV R1,#30H		;除数起始字节	
		MOV R2,#3		;要被减的字节数
		MOV R3,#43H		;当前字节的商存储地址
		MOV R4,#4		;总共要进行的错位除法次数（最外层循环次数）
		
MINUS2:
		CLR C
		ACALL COMPARE	;比较除数与被除数大小
		JC NEXTCIR		;若除数大于被除数，进入下一轮循环

MINUS1:			;化除法为减法，一次减法从当前字节循环至被除数最高字节
		MOV A,@R0
		SUBB A,@R1		
		MOV @R0,A		;存余数
		INC R0
		INC R1
		DJNZ R2,MINUS1
		
		CLR C
		MOV R2,B
		ACALL BACK	;调整R0和R1的值，便于下一轮循环
		MOV A,R3
		MOV R1,A
		MOV A,@R1
		ADDC A,#01H	;一次减法执行完等同于商加一
		MOV @R1,A		;存商
		MOV R1,#30H	
		SJMP MINUS2

NEXTCIR:			;当高3字节的减法执行至被减数小于减数，往低字节顺延一个字节，进行下一个大循环
		DEC R0
		INC R2
		DEC R3
		DJNZ R4,MINUS2
		
Loop:	
      jmp Loop

子程序如下：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
COMPARE:		;比较被减数与减数大小的子程序
						;不改变存储内容
		MOV B,R2	;使用B寄存器保护R2的值
INCOMPARE:		;若减到最高位产生借位，CY=1，被减数小于减数
		MOV A,@R0
		SUBB A,@R1
		INC R0
		INC R1
		DJNZ R2,INCOMPARE
		MOV R2,B	;归还R2
BACK:					;将寄存器内容恢复到调用子程序之前
		DEC R0
		DEC R1
		DJNZ R2,BACK
		MOV R2,B
		RET

这里需要说明一下，如果你要像我一样使用ACALL来调用子程序的话，最好设定一下主程序和子程序的代码存储地址。主程序可以使用从0030H开始的存储，即ORG 0030H，子程序的代码存储地址不能超出ACALL的调用范围，按照我的主程序代码长度，设为ORG 0100H是可以的。

当然，也可以直接使用LCALL，比较省事。

4、测试结果

我们随便选择一组数据进行测试

本次选择的测试数据如下：

1
2
3
4
5
6
7
8
9
10
11
12
13
;被除数赋值，从20H单元开始存储，低位数存储在低字节地址，高位数存储在高字节地址
		MOV 25H,#1DH	
		MOV 24H,#45H
		MOV 23H,#0BAH
		MOV 22H,#7FH
		MOV 21H,#0A0H
		MOV 20H,#39H

;除数赋值，存储规则同1
		MOV 32H,#1FH	
		MOV 31H,#58H
		MOV 30H,#0ACH

即：1D 45 BA 7F A0 39 ÷ 1F 58 AC

Proteus程序运行结果

商：EF0FE2 余数：0D4461